Managing printers at the command-line

This post provides a method of using the command-line to add printer drivers to a Windows 2003 print server, and then create and configure the port and printer. You can use this to create a control file with your printers, and then run these commands against the control file. There are also a few commands to gather information from your printer server(s) from the directory and event log.

Adding a driver

The printuientry calls have slightly different syntax between XP and 2003, hence the OS specific commands below even though the same print server is being targeted:

The Driver model name should be extracted from the INF and replace the example HP UPD driver.

On XP against a 32-bit print server:
rundll32 printui.dll,PrintUIEntry /ia /c\\printserver /m "HP Universal Printing PCL 6" /h "Intel" /v "Windows 2000 or XP" /f \\server\drivers\hpupd_pcl6_x86\hpu4pdpc.inf

On a 2003 x64 server, serving x86 clients (therefore both drivers are required):
rundll32 printui.dll,PrintUIEntry /ia /c \\printserver /m "HP Universal Printing PCL 6" /h "x64" /v "Windows XP and Windows Server 2003" /f file://server/drivers/hpupd_pcl6_x64/hpu4pdpc.inf

rundll32 printui.dll,PrintUIEntry /ia /c \\printserver /m "HP Universal Printing PCL 6" /h "x86" /v "Windows 2000, Windows XP and Windows Server 2003" /f \\server\drivers\hpupd_pcl6_x86\hpu4pdpc.inf

Creating ports/printers

Create a control file containing:
<PRINTER_NAME>,<PRINTER_IP>,<PRINTER_DRIVER>,<PRINTER_LOCATION>

For example:
Printer1,192.168.0.10,HP Universal Printing PCL 6,Printer/Location/1

Ping the IP Address for the printer:
for /f "tokens=1-4 delims=," %i in (controlfile) do @echo. &@echo %i,%j,%k,%l &@ping -n 1 %j

Register the prnadmin.dll if not already done:
cd /d "C:\Program Files\Windows Resource Kits\Tools" && regsvr32 /s prnadmin.dll

Assuming the driver is already installed, Add a DNS record create the port, Use the Microsoft Windows Resource Kit Tools to create the port and printer, configure the share and publish to AD, set duplex defaults, grant permissions to manage printers to a security group and ensure the print processor is winprint

for /f "tokens=1-4 delims=," %i in (controlfile) do @echo dnscmd %ad_dns_server% /recordadd %domain% %i A %j

for /f "tokens=1-4 delims=," %i in (controlfile) do @cscript portmgr.vbs -a -c \\printserver -p %i -h %j -t LPR -q %i

for /f "tokens=1-4 delims=," %i in (controlfile) do @cscript prnmgr.vbs -a -c \\printserver -b %i -m "%k" -r %i

for /f "tokens=1-4 delims=," %i in (controlfile) do @cscript prncfg.vbs -s -b \\printserver\%i -h %i -l "%l" +published

for /f "tokens=1-4 delims=," %i in (controlfile) do @setprinter \\printserver\%i 8 "pDevMode=dmDuplex=2,dmCollate=1,dmFields=duplex collate"

for /f "tokens=1-4 delims=," %i in (controlfile) do @c:\util\subinacl /printer \\printserver\%i /grant=domain\group=M

for /f "tokens=1-4 delims=," %i in (controlfile) do @setprinter \\printserver\%i 2 pPrintProcessor="WinPrint"

Print a test page to each printer:
for /f "tokens=1-4 delims=," %i in (controlfile) do cscript prnctrl.vbs -t -b \\printserver\%i

Check the printer is published in AD:
for /f "tokens=1-4 delims=," %i in (controlfile) do dsquery * CN=printserver,OU=ServerOU,DC=domain,DC=com -filter "(&(printShareName=%i))"

Note that subinacl.exe in the rktools isn't very functional, 5.2.3790.1180 is much better:
http://www.microsoft.com/downloads/details.aspx?FamilyID=E8BA3E56-D8FE-4A91-93CF-ED6985E3927B

Gathering information from a print server

Export Print Server details:
dsquery * OU=ServerOU,DC=domain,DC=com -limit 0 -filter "(&(objectClass=printQueue)(objectCategory=printQueue))" -attr cn printerName driverName printCollate printColor printLanguage printSpooling driverVersion printStaplingSupported printMemory printRate printRateUnit printMediaReady

csvde -f PrinterDetails.csv -d OU=ServerOU,DC=domain,DC=com -r "(&(objectClass=printQueue)(objectCategory=printQueue))" -l cn,printerName,location,driverName,printCollate,printColor,printLanguage,printSpooling,driverVersion,printStaplingSupported,printMemory,printRate,printRateUnit,printMediaReady
Dump event logs for the last day:
c:\util\dumpel -s \\printserver -l System -e 10 -m Print -d 1

Wayne's World of IT (WWoIT), Copyright 2008 Wayne Martin.